function fishy -d "Run fish in a non-standard way" -a fishy_opt
    if test -z "$fishy_opt"
        printf "How do you want to run fish?\n 1) With stock configuration\n 2) With stock configuration in private mode\n 3) With existing configuration in private mode\n"
        read fishy_opt -P "> "
    end
    switch $fishy_opt
        case 1
            echo '[info] Starting fish with stock configuration.'
            echo '[info] Command: `HOME=(mktemp -d) fish`'
            HOME=(mktemp -d) fish
        case 2
            echo '[info] Starting fish with stock configuration in private mode.'
            echo '[info] Command: `HOME=(mktemp -d) fish --private`'
            HOME=(mktemp -d) fish --private
        case 3
            echo '[info] Starting fish with existing configuration in private mode.'
            echo '[info] Command: `fish --private`'
            fish --private
        case '*'
            echo (set_color red)"Invalid option: [$fishy_opt]"(set_color normal)
            return 1
    end
end