From ae9e4adf8b48834440ce8fe457af762d99b3fb18 Mon Sep 17 00:00:00 2001
From: Charles Gould <charles@gould.dev>
Date: Mon, 23 Dec 2024 00:08:58 -0600
Subject: [PATCH] fish: remove unused nvm plugin

---
 fish/completions/nvm.fish                   |  21 --
 fish/conf.d/nvm.fish                        |  28 ---
 fish/fish_plugins                           |   1 -
 fish/functions/_nvm_index_update.fish       |  20 --
 fish/functions/_nvm_list.fish               |  14 --
 fish/functions/_nvm_version_activate.fish   |   4 -
 fish/functions/_nvm_version_deactivate.fish |   5 -
 fish/functions/nvm.fish                     | 234 --------------------
 8 files changed, 327 deletions(-)
 delete mode 100644 fish/completions/nvm.fish
 delete mode 100644 fish/conf.d/nvm.fish
 delete mode 100644 fish/functions/_nvm_index_update.fish
 delete mode 100644 fish/functions/_nvm_list.fish
 delete mode 100644 fish/functions/_nvm_version_activate.fish
 delete mode 100644 fish/functions/_nvm_version_deactivate.fish
 delete mode 100644 fish/functions/nvm.fish

diff --git a/fish/completions/nvm.fish b/fish/completions/nvm.fish
deleted file mode 100644
index 14be1b7..0000000
--- a/fish/completions/nvm.fish
+++ /dev/null
@@ -1,21 +0,0 @@
-complete --command nvm --exclusive
-complete --command nvm --exclusive --long version --description "Print version"
-complete --command nvm --exclusive --long help --description "Print help"
-complete --command nvm --long silent --description "Suppress standard output"
-
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments install --description "Download and activate the specified Node version"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments use --description "Activate the specified Node version in the current shell"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments list --description "List installed Node versions"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments list-remote --description "List available Node versions to install"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments current --description "Print the currently-active Node version"
-complete --command nvm --exclusive --condition "__fish_seen_subcommand_from install" --arguments "(
-    test -e $nvm_data && string split ' ' <$nvm_data/.index
-)"
-complete --command nvm --exclusive --condition "__fish_seen_subcommand_from use" --arguments "(_nvm_list | string split ' ')"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments uninstall --description "Uninstall the specified Node version"
-complete --command nvm --exclusive --condition "__fish_seen_subcommand_from uninstall" --arguments "(
-    _nvm_list | string split ' ' | string replace system ''
-)"
-complete --command nvm --exclusive --condition "__fish_seen_subcommand_from use uninstall" --arguments "(
-    set --query nvm_default_version && echo default
-)"
diff --git a/fish/conf.d/nvm.fish b/fish/conf.d/nvm.fish
deleted file mode 100644
index e060f2f..0000000
--- a/fish/conf.d/nvm.fish
+++ /dev/null
@@ -1,28 +0,0 @@
-set --query nvm_mirror || set --global nvm_mirror https://nodejs.org/dist
-set --query XDG_DATA_HOME || set --local XDG_DATA_HOME ~/.local/share
-set --global nvm_data $XDG_DATA_HOME/nvm
-
-function _nvm_install --on-event nvm_install
-    test ! -d $nvm_data && command mkdir -p $nvm_data
-    echo "Downloading the Node distribution index..." 2>/dev/null
-    _nvm_index_update
-end
-
-function _nvm_update --on-event nvm_update
-    set --query --universal nvm_data && set --erase --universal nvm_data
-    set --query --universal nvm_mirror && set --erase --universal nvm_mirror
-    set --query nvm_mirror || set --global nvm_mirror https://nodejs.org/dist
-end
-
-function _nvm_uninstall --on-event nvm_uninstall
-    command rm -rf $nvm_data
-
-    set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
-
-    set --names | string replace --filter --regex -- "^nvm" "set --erase nvm" | source
-    functions --erase (functions --all | string match --entire --regex -- "^_nvm_")
-end
-
-if status is-interactive && set --query nvm_default_version && ! set --query nvm_current_version
-    nvm use --silent $nvm_default_version
-end
diff --git a/fish/fish_plugins b/fish/fish_plugins
index 2c7f7d5..9e49cc3 100644
--- a/fish/fish_plugins
+++ b/fish/fish_plugins
@@ -1,4 +1,3 @@
 jorgebucaran/fisher
-jorgebucaran/nvm.fish
 lilyball/nix-env.fish
 reitzig/sdkman-for-fish@v2.1.0
diff --git a/fish/functions/_nvm_index_update.fish b/fish/functions/_nvm_index_update.fish
deleted file mode 100644
index c66753d..0000000
--- a/fish/functions/_nvm_index_update.fish
+++ /dev/null
@@ -1,20 +0,0 @@
-function _nvm_index_update
-    test ! -d $nvm_data && command mkdir -p $nvm_data
-
-    set --local index $nvm_data/.index
-
-    if not command curl -q --location --silent $nvm_mirror/index.tab >$index.temp
-        command rm -f $index.temp
-        echo "nvm: Can't update index, host unavailable: \"$nvm_mirror\"" >&2
-        return 1
-    end
-
-    command awk -v OFS=\t '
-        /v0.9.12/ { exit } # Unsupported
-        NR > 1 {
-            print $1 (NR == 2  ? " latest" : $10 != "-" ? " lts/" tolower($10) : "")
-        }
-    ' $index.temp >$index
-
-    command rm -f $index.temp
-end
diff --git a/fish/functions/_nvm_list.fish b/fish/functions/_nvm_list.fish
deleted file mode 100644
index 1623bb8..0000000
--- a/fish/functions/_nvm_list.fish
+++ /dev/null
@@ -1,14 +0,0 @@
-function _nvm_list
-    set --local versions $nvm_data/*
-
-    set --query versions[1] &&
-        string match --entire --regex -- (
-            string replace --all -- $nvm_data/ "" $versions |
-            string match --regex -- "v\d.+" |
-            string escape --style=regex |
-            string join "|"
-        ) <$nvm_data/.index
-
-    command --all node |
-        string match --quiet --invert --regex -- "^$nvm_data" && echo system
-end
diff --git a/fish/functions/_nvm_version_activate.fish b/fish/functions/_nvm_version_activate.fish
deleted file mode 100644
index f7dfef7..0000000
--- a/fish/functions/_nvm_version_activate.fish
+++ /dev/null
@@ -1,4 +0,0 @@
-function _nvm_version_activate --argument-names ver
-    set --global --export nvm_current_version $ver
-    set --prepend PATH $nvm_data/$ver/bin
-end
diff --git a/fish/functions/_nvm_version_deactivate.fish b/fish/functions/_nvm_version_deactivate.fish
deleted file mode 100644
index 24dd36e..0000000
--- a/fish/functions/_nvm_version_deactivate.fish
+++ /dev/null
@@ -1,5 +0,0 @@
-function _nvm_version_deactivate --argument-names ver
-    test "$nvm_current_version" = "$ver" && set --erase nvm_current_version
-    set --local index (contains --index -- $nvm_data/$ver/bin $PATH) &&
-        set --erase PATH[$index]
-end
diff --git a/fish/functions/nvm.fish b/fish/functions/nvm.fish
deleted file mode 100644
index b7d70de..0000000
--- a/fish/functions/nvm.fish
+++ /dev/null
@@ -1,234 +0,0 @@
-function nvm --description "Node version manager"
-    for silent in --silent -s
-        if set --local index (contains --index -- $silent $argv)
-            set --erase argv[$index] && break
-        end
-        set --erase silent
-    end
-
-    set --local cmd $argv[1]
-    set --local ver $argv[2]
-
-    if set --query silent && ! set --query cmd[1]
-        echo "nvm: Version number not specified (see nvm -h for usage)" >&2
-        return 1
-    end
-
-    if ! set --query ver[1] && contains -- "$cmd" install use
-        for file in .nvmrc .node-version
-            set file (_nvm_find_up $PWD $file) && read ver <$file && break
-        end
-
-        if ! set --query ver[1]
-            echo "nvm: Invalid version or missing \".nvmrc\" file" >&2
-            return 1
-        end
-    end
-
-    set --local their_version $ver
-
-    switch "$cmd"
-        case -v --version
-            echo "nvm, version 2.2.16"
-        case "" -h --help
-            echo "Usage: nvm install <version>    Download and activate the specified Node version"
-            echo "       nvm install              Install the version specified in the nearest .nvmrc file"
-            echo "       nvm use <version>        Activate the specified Node version in the current shell"
-            echo "       nvm use                  Activate the version specified in the nearest .nvmrc file"
-            echo "       nvm list                 List installed Node versions"
-            echo "       nvm list-remote          List available Node versions to install"
-            echo "       nvm list-remote <regex>  List Node versions matching a given regex pattern"
-            echo "       nvm current              Print the currently-active Node version"
-            echo "       nvm uninstall <version>  Uninstall the specified Node version"
-            echo "Options:"
-            echo "       -s, --silent             Suppress standard output"
-            echo "       -v, --version            Print the version of nvm"
-            echo "       -h, --help               Print this help message"
-            echo "Variables:"
-            echo "       nvm_arch                 Override architecture, e.g. x64-musl"
-            echo "       nvm_mirror               Use a mirror for downloading Node binaries"
-            echo "       nvm_default_version      Set the default version for new shells"
-            echo "       nvm_default_packages     Install a list of packages every time a Node version is installed"
-            echo "Examples:"
-            echo "       nvm install latest       Install the latest version of Node"
-            echo "       nvm use 14.15.1          Use Node version 14.15.1"
-            echo "       nvm use system           Activate the system's Node version"
-
-        case install
-            _nvm_index_update
-
-            string match --entire --regex -- (_nvm_version_match $ver) <$nvm_data/.index | read ver alias
-
-            if ! set --query ver[1]
-                echo "nvm: Invalid version number or alias: \"$their_version\"" >&2
-                return 1
-            end
-
-            if test ! -e $nvm_data/$ver
-                set --local os (command uname -s | string lower)
-                set --local ext tar.gz
-                set --local arch (command uname -m)
-
-                switch $os
-                    case aix
-                        set arch ppc64
-                    case sunos
-                    case linux
-                    case darwin
-                    case {MSYS_NT,MINGW\*_NT}\*
-                        set os win
-                        set ext zip
-                    case \*
-                        echo "nvm: Unsupported operating system: \"$os\"" >&2
-                        return 1
-                end
-
-                switch $arch
-                    case i\*86
-                        set arch x86
-                    case x86_64
-                        set arch x64
-                    case arm64
-                        string match --regex --quiet "v(?<major>\d+)" $ver
-                        if test "$os" = darwin -a $major -lt 16
-                            set arch x64
-                        end
-                    case armv6 armv6l
-                        set arch armv6l
-                    case armv7 armv7l
-                        set arch armv7l
-                    case armv8 armv8l aarch64
-                        set arch arm64
-                end
-
-                set --query nvm_arch && set arch $nvm_arch
-
-                set --local dir "node-$ver-$os-$arch"
-                set --local url $nvm_mirror/$ver/$dir.$ext
-
-                command mkdir -p $nvm_data/$ver
-
-                if ! set --query silent
-                    echo -e "Installing Node \x1b[1m$ver\x1b[22m $alias"
-                    echo -e "Fetching \x1b[4m$url\x1b[24m\x1b[7m"
-                end
-
-                if ! command curl -q $silent --progress-bar --location $url |
-                        command tar --extract --gzip --directory $nvm_data/$ver 2>/dev/null
-                    command rm -rf $nvm_data/$ver
-                    echo -e "\033[F\33[2K\x1b[0mnvm: Invalid mirror or host unavailable: \"$url\"" >&2
-                    return 1
-                end
-
-                set --query silent || echo -en "\033[F\33[2K\x1b[0m"
-
-                if test "$os" = win
-                    command mv $nvm_data/$ver/$dir $nvm_data/$ver/bin
-                else
-                    command mv $nvm_data/$ver/$dir/* $nvm_data/$ver
-                    command rm -rf $nvm_data/$ver/$dir
-                end
-            end
-
-            if test $ver != "$nvm_current_version"
-                set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
-                _nvm_version_activate $ver
-
-                set --query nvm_default_packages[1] && npm install --global $silent $nvm_default_packages
-            end
-
-            set --query silent || printf "Now using Node %s (npm %s) %s\n" (_nvm_node_info)
-        case use
-            test $ver = default && set ver $nvm_default_version
-            _nvm_list | string match --entire --regex -- (_nvm_version_match $ver) | read ver __
-
-            if ! set --query ver[1]
-                echo "nvm: Can't use Node \"$their_version\", version must be installed first" >&2
-                return 1
-            end
-
-            if test $ver != "$nvm_current_version"
-                set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
-                test $ver != system && _nvm_version_activate $ver
-            end
-
-            set --query silent || printf "Now using Node %s (npm %s) %s\n" (_nvm_node_info)
-        case uninstall
-            if test -z "$ver"
-                echo "nvm: Not enough arguments for command: \"$cmd\"" >&2
-                return 1
-            end
-
-            test $ver = default && test ! -z "$nvm_default_version" && set ver $nvm_default_version
-
-            _nvm_list | string match --entire --regex -- (_nvm_version_match $ver) | read ver __
-
-            if ! set -q ver[1]
-                echo "nvm: Node version not installed or invalid: \"$their_version\"" >&2
-                return 1
-            end
-
-            set --query silent || printf "Uninstalling Node %s %s\n" $ver (string replace ~ \~ "$nvm_data/$ver/bin/node")
-
-            _nvm_version_deactivate $ver
-
-            command rm -rf $nvm_data/$ver
-        case current
-            _nvm_current
-        case ls list
-            _nvm_list | _nvm_list_format (_nvm_current) $argv[2]
-        case lsr {ls,list}-remote
-            _nvm_index_update || return
-            _nvm_list | command awk '
-                FILENAME == "-" && (is_local[$1] = FNR == NR) { next } {
-                    print $0 (is_local[$1] ? " ✓" : "")
-                }
-            ' - $nvm_data/.index | _nvm_list_format (_nvm_current) $argv[2]
-        case \*
-            echo "nvm: Unknown command or option: \"$cmd\" (see nvm -h for usage)" >&2
-            return 1
-    end
-end
-
-function _nvm_find_up --argument-names path file
-    test -e "$path/$file" && echo $path/$file || begin
-        test ! -z "$path" || return
-        _nvm_find_up (string replace --regex -- '/[^/]*$' "" $path) $file
-    end
-end
-
-function _nvm_version_match --argument-names ver
-    string replace --regex -- '^v?(\d+|\d+\.\d+)$' 'v$1.' $ver |
-        string replace --filter --regex -- '^v?(\d+)' 'v$1' |
-        string escape --style=regex || string lower '\b'$ver'(?:/\w+)?$'
-end
-
-function _nvm_list_format --argument-names current regex
-    command awk -v current="$current" -v regex="$regex" '
-        $0 ~ regex {
-            aliases[versions[i++] = $1] = $2 " " $3
-            pad = (n = length($1)) > pad ? n : pad
-        }
-        END {
-            if (!i) exit 1
-            while (i--)
-                printf((current == versions[i] ? " ▶ " : "   ") "%"pad"s %s\n",
-                    versions[i], aliases[versions[i]])
-        }
-    '
-end
-
-function _nvm_current
-    command --search --quiet node || return
-    set --query nvm_current_version && echo $nvm_current_version || echo system
-end
-
-function _nvm_node_info
-    set --local npm_path (string replace bin/npm-cli.js "" (realpath (command --search npm)))
-    test -f $npm_path/package.json || set --local npm_version_default (command npm --version)
-    command node --eval "
-        console.log(process.version)
-        console.log('$npm_version_default' ? '$npm_version_default': require('$npm_path/package.json').version)
-        console.log(process.execPath)
-    " | string replace -- ~ \~
-end